CFX-9850G PLUS: Program FAIRDIE

ClrText
ClrGraph
ClrList
"FAIR DIE ?"
"1 FOR YES"
"0 FOR NO"
? --> A
"NUM OF EXPERIMENTS:"
? --> M
"NUM OF ROLLS:"
? --> N
N/6 --> E
M --> Dim List1
6 --> Dim List2
0 --> K
ClrText
  Lbl M
  K+1 --> K
  0*List 2 --> List 2
    If A=1
      Then For 1 --> I To N Step 1
      Int (6*Ran#+1) --> D
      List 2[D]+1 --> List 2[D]
      Next
    Else For 1 --> I To N Step 1
      Int (11*Ran#) --> R
      Int (R/2)+1 --> D
      List 2[D]+1 --> List 2[D]
      Next
    IfEnd
  Sum (((List 2-E)^2)/E) --> C
  Locate 1,1,"EXP. NO:"
  Locate 10,2,K
  Locate 1,3,"CHI¨2="
  Locate 10,4,C
  C --> List 1[K]
  If K< M
  Then Goto M
  IfEnd
ClrText
Locate 1,2,"NUM OF EXPERIMENTS:"
Locate 10,3,M
Locate 1,4,"NUM OF ROLLS:"
Locate 10,5,N
Locate 1,6,"CODE FAIRDIE:"
Locate 10,7,A
SortA(List 1)
Stop

CFX-9850G PLUS: Program PRIMFREQ

ClrText
"A MOMENT PLEASE, BUSY ..."
0 --> L
M --> Dim List 2
M --> Dim List 3
 Lbl S
   List 1[1] --> List 2[1]
   1 --> List 3[1]
   1 --> K
   1 --> I
     Lbl P
     K+1 --> K
      If List 1[K]=List 1[K-1]
      Then Goto Q
      IfEnd
     I+1 --> I
     List 1[K] --> List 2[I]
     1 --> List 3[I]
     Goto R
  Lbl Q
  List 3[I]+1 --> List 3[I]
  Lbl R
   If K< M
   Then Goto P
   IfEnd
  If L=1
  Then Goto T
  IfEnd
I --> Dim List 2
I --> Dim List 3
1 --> L
Goto S
Lbl T
ClrText
Locate 1,2,"PRIMFREQ FINISHED"
Stop


CFX-9850G PLUS: Program SECUFREQ

"A MOMENT PLEASE, BUSY ..."
Dim List 2 --> A
Int (List 2[A]+2) --> Dim List 4
Int (List 2[A]+2) --> Dim List 5
Int (List 2[A]+1) --> B
Seq(-.5+X,X,0,B,1) --> List 4
0 --> List 4[1]
0*List 4 --> List 5
0 --> K
 Lbl Q
   K+1 --> K
   Int (List 1[K])+2 --> L
   List 5[L]+1 --> List 5[L]
  If K< M
  Then Goto Q
  IfEnd
List 5[2] --> List 5[1]
ClrText
Locate 1,2,"SECUFREQ FINISHED"
Stop